Yes, this can be done with a small customization.
You can't move the standard Notes system part from Attachments to Details, but you can add a custom FactBox to the existing Details area and display the same notes there.
For example, on the Customer Card:
page 50100 "Customer Notes FactBox"
{
PageType = CardPart;
ApplicationArea = All;
Caption = 'Notes';
SourceTable = Customer;
layout
{
area(Content)
{
field(NoteText; NoteText)
{
ApplicationArea = All;
Editable = false;
MultiLine = true;
ShowCaption = false;
}
}
}
trigger OnAfterGetRecord()
begin
LoadNotes();
end;
local procedure LoadNotes()
var
RecordLink: Record "Record Link";
RecordLinkMgt: Codeunit "Record Link Management";
begin
Clear(NoteText);
RecordLink.SetRange("Record ID", Rec.RecordId);
RecordLink.SetRange(Type, RecordLink.Type::Note);
RecordLink.SetAutoCalcFields(Note);
if RecordLink.FindSet() then
repeat
if NoteText <> '' then
NoteText += '\';
NoteText += RecordLinkMgt.ReadNote(RecordLink);
until RecordLink.Next() = 0;
end;
var
NoteText: Text;
}
Then add it to the existing Customer Card FactBox area:
pageextension 50101 "Customer Card Notes Ext" extends "Customer Card"
{
layout
{
addlast(FactBoxes)
{
part(CustomerNotes; "Customer Notes FactBox")
{
ApplicationArea = All;
SubPageLink = "No." = field("No.");
}
}
}
}
This doesn't move or modify the standard Notes functionality. It simply reads the same notes and displays them in the custom FactBox.
Hope this helps. If it works for you, please mark the answer as Accepted Answer. 🙂
Sanket
