Dynamics 365 Business Central: ShowMandatory for Enum, Option, and Integer Fields

Have you ever tried to mark an Enum, Option, or Integer field as mandatory in Business Central, but the red asterisk simply refuses to appear—even after setting ShowMandatory = true;?

If yes, you’re not alone

When designing pages in Microsoft Dynamics 365 Business Central, we often want to clearly tell users which fields must be filled in.

In AL, the first property we think of is:

ShowMandatory = true;

This draws the red asterisk next to the field in the UI and visually marks it as required.

But there is a catch.

For numeric, enum, and option fields, you might have noticed that even after setting ShowMandatory = true; the red asterisk doesn’t always behave as expected.

Why does this happen, and how do we fix it?

Let’s walk through it step by step.

The Core Idea

• For Text fields, “blank” truly means empty – no characters.

• For Integer, Decimal, Enum, Option, the field always has some value (often 0 or the first enum/option member), even when the user hasn’t chosen anything yet.

Business Central therefore doesn’t see these fields as “blank”, so the mandatory indicator behaves differently.

That’s where the BlankZero property helps. It tells Business Central:

“Treat zero or the default value as visually blank for this field.”

When ShowMandatory = true; and BlankZero = true; work together, the red asterisk is shown until the user selects or enters a meaningful value.

Table Extension:

tableextension 50425 CustomerExt extends "Customer"

{

    fields

    {

        field(50100; "Customer Category"; Enum "Customer Category")

        {

            Caption = 'Customer Category';

            DataClassification = CustomerContent;

        }

        field(50101; "Customer Fix Category"; Text[100])

        {

            Caption = 'Customer Fix Category';

            DataClassification = CustomerContent;

        }

        field(50102; "Customer Option Category"; Option)

        {

            Caption = 'Customer Option Category';

            DataClassification = CustomerContent;

            OptionMembers = " ","Option1","Option2","Option3";

        }

         field(50103; "Customer Category Integer"; Integer)

        {

            Caption = 'Customer Category Integer';

            DataClassification = CustomerContent;

        }

    }

}

Key points:

Customer Category is an Enum.

Customer Fix Category is Text.

Customer Option Category is an Option with a blank first member.

Customer Category Integer is an Integer.

Enum:

enum 50400 "Customer Category"

{

    Extensible = true;

    value(0; " ")

    {

        Caption = ' ';

    }

    value(1; "Retail")

    {

        Caption = 'Retail';

    }

    value(2; "Industrial")

    {

        Caption = 'Industrial';

    }

    value(3; "Government")

    {

        Caption = 'Government';

    }

}

Here, value 0 is intentionally a blank value. This is important because BlankZero uses this default to decide when to treat the field as “empty”.

Page Extension:

Now we mark these fields as mandatory and control how they appear.

pageextension 50400 CustomerCardExt extends "Customer Card"

{

    layout

    {

        addlast(General)

        {

            field("Customer Category"; Rec."Customer Category")

            {

                ApplicationArea = All;

                ShowMandatory = true;

                Editable = true;

                BlankZero = true;

            }

            field("Customer Fix Category"; Rec."Customer Fix Category")

            {

                ApplicationArea = All;

                ShowMandatory = true;

            }

            field("Customer Option Category"; Rec."Customer Option Category")

            {

                ApplicationArea = All;

                ShowMandatory = (Rec."Customer Category" = Rec."Customer Category"::" ");

                BlankZero = true;

            }

             field("Customer Category Integer"; Rec."Customer Category Integer")

            {

                ApplicationArea = All;

                ShowMandatory = true;

                BlankZero = true;

            }

        }

    }

}

Output:

Thanks For Reading...!!

Regards,

Khushbu Rajvi