Dynamics Community Forum Thread Details

How to cancel a Purchase Order in X++

Hi!

This is a custom class. The class has run(), cancelMarkup() and parmPurchTable() methods.

private void cancelMarkup(
    TableId     _transTableId,
    RecId       _transRecId
    )
{
    MarkupTrans         markupTrans;

    while select forupdate * from markupTrans
        where markupTrans.TransRecId == _transRecId
           && markupTrans.TransTableId == _transTableId
           && markupTrans.MarkupCategory == MarkupCategory::Fixed
           && !markupTrans.IsDeleted
    {
        markupTrans.Value = 0;
        markupTrans.update();
    }
}

/// <summary>
/// Performs the purchase order cancelation.
/// </summary>
public void run()
{
    PurchLine purchLine;
    PurchPrepayTable purchPrepayTable;
    PurchQty  purchQty;
    boolean   hasLines = false;
    boolean   messageShown = false;
    PdsCWInventQty  pdsCWQty;
    // <GBR>
    boolean   clearFiscalDocumentRef_BR = false;
    NoYes     isBrazilEnabled = BrazilParameters::isEnabled();
    // </GBR>
    McrOrderEventTable mcrOrderEventTable;

    ttsbegin;

    //selects a prepayment definition which does not have a paid or settled prepayment invoice
    select firstonly forupdate PrepayApplicationRemaining from purchPrepayTable
        where purchPrepayTable.PurchTable == purchTable.PurchId
        && purchPrepayTable.IsDeleted == NoYes::No;

    if (purchPrepayTable)
    {
        if (purchPrepayTable.PrepayApplicationRemaining == 0.0)
        {
            //reverses the prepayment invoices which have not been paid or settled
            PurchPrepayTable::reverseUnpaidPostedAdvances(purchTable.PurchId);
            purchPrepayTable.Value = 0.0;
            purchPrepayTable.PrepayLimit = 0.0;
            purchPrepayTable.PrepayAvailable = 0.0;
            purchPrepayTable.Description = '';
            purchPrepayTable.PrepayCategoryId = 0;
            purchPrepayTable.update();
        }
        else
        {
            //throws error and returns with message that a paid prepayment invoice exists therefore purchase order cannot be cancelled
            throw error(strFmt("@SYS341265", purchTable.PurchId));
        }
    }

    if (purchTable.ChangeRequestRequired && purchTable.DocumentState >= VersioningDocumentState::Approved)
    {
        if (!purchTable.selectForUpdate())
        {
            purchTable = PurchTable::findRecId(purchTable.RecId, true);
        }
        VersioningPurchaseOrder::newPurchaseOrder(purchTable).createChangeRequest();
    }
    else if (!VersioningPurchaseOrder::newPurchaseOrder(purchTable).isLastVersionArchived() && purchTable.DocumentState == VersioningDocumentState::Confirmed)
    {
        // force archiving to avoid it during line cancellation as that would lead to update conflicts.
        purchTable.update();
    }

    // do not cancel invoice matched lines.
    while select forupdate purchLine
        where purchLine.PurchId             == purchTable.PurchId
           && purchLine.IsDeleted           == NoYes::No
    {
        hasLines = true;
        if (purchLine.IsInvoiceMatched == NoYes::Yes)
        {
            if (purchLine.PurchStatus != PurchStatus::Invoiced)
            {
                if (!messageShown)
                {
                    info("@SYS342633");
                    messageShown = true;
                }
                info(strFmt("@SYS342634", purchLine.LineNumber, purchLine.ItemId));
            }
        }
        else
        {
            if (pdsIsCWItem(purchLine.ItemId))
            {
                pdsCWQty = purchLine.pdsCWReceivedInTotal() + purchLine.pdsCWArrived() + purchLine.pdsCWRegistered();
            }
            else
            {
                pdsCWQty = 0;
            }
            purchQty = purchLine.receivedInTotal() + purchLine.arrivedInPurchUnit() + purchLine.registeredInPurchUnit();
            if (purchQty)
            {
                // if anything was recieved, arrived or registered then write down to what was recieved, arrived and registered.
                purchLine.PurchQty      = purchQty;
                purchLine.PdsCWQty      = pdsCWQty;
                purchLine.LineAmount    = purchLine.calcLineAmountForced();
            }
            else
            {
                purchLine.PurchQty      = 0;
                purchLine.LineAmount    = 0;
                purchLine.PdsCWQty      = 0;
                purchLine.PurchStatus = PurchStatus::Canceled;
                // <GBR>
                if (isBrazilEnabled)
                {
                    clearFiscalDocumentRef_BR = true;
                }
                // </GBR>
                if (purchLine.isDropShipment() &&
                    purchTable.InterCompanyDirectDelivery == NoYes::Yes)
                {
                    purchTable.InterCompanyDirectDelivery = NoYes::No;
                    purchTable.doUpdate();
                }
            }

            InventMovement::bufferSetTransQtyUnit(purchLine);
            InventMovement::bufferSetRemainQty(purchLine);

            // now cancel the markup
            this.cancelMarkup(purchLine.TableId, purchLine.RecId);

            purchLine.update(false, true, false);
        }
    }

    // cancel header markup
    this.cancelMarkup(purchTable.TableId, purchTable.RecId);

    if (!hasLines)
    {
        purchTable.PurchStatus = PurchStatus::Canceled;
        purchTable.update();
    }

    // <GBR>
    if (isBrazilEnabled && (clearFiscalDocumentRef_BR || !hasLines))
    {
        purchTable.removeInvoiceRefRecId_BR();
    }
     // </GBR>

    if ( purchTable.MCRDropShipment )
    {
        mcrOrderEventTable.insertFromDropShipment(purchTable.referenceSalesTable().SalesId, purchTable.PurchId, MCROrderEventType::CancelDropShipPO);
    }

    ttscommit;

    PurchPrepayTable::checkApplicationRemaining(purchTable.PurchId, purchTable.InvoiceAccount);
}

Quick Links

Leaderboard > 🔒一 Microsoft Dynamics AX (Archived)