I agree this is a real pain. 99% of the time I don't want to re-import I just want to download the data to my machine, not on-line, and work on it. What were MSFT thinking? I don't want it formatted as a table, I don't want data validation and I don't want hidden columns and worksheets. I created a quick excel macro to undo all this rubbish. Add a keyboard shortcut of your choice and it makes reverting to something more usable an easy step. Use at your own discretion / risk but it works fine for me.
Sub ConvertCRMExport()
'
'CRM 2015 Update 1 changes Excel Download to a formatted table in a .xlsx sheet which also contains hidden columns and hidden worksheets
' to allow re-import none of which are needed for normal data manipulation i.e. 99% of the time
'
'This macro converts the table back to a range, removes table formatting, removes data validation,
' deletes the three unwanted columns and the hidden worksheet
' It finally saves, closes and reopens the workbook so that the copy and paste multiple selection bug is overcome.
'
'
'
Dim crmList As Range
Dim Tgt As Workbook
Dim TgtPath As String
On Error GoTo ErrHandle
ActiveWorkbook.Worksheets("hiddenSheet").Visible = xlSheetVisible
For Each n In ActiveWorkbook.Worksheets("hiddenSheet").UsedRange.Cells
n.Value = ""
Next
Application.ScreenUpdating = False
Application.DisplayAlerts = False
ActiveWorkbook.Worksheets("hiddenSheet").Delete
With ActiveSheet.ListObjects("Table1")
Set crmList = .Range
.Unlist
End With
With crmList
.Interior.ColorIndex = xlColorIndexNone
.Font.ColorIndex = xlColorIndexAutomatic
.Borders.LineStyle = xlLineStyleNone
End With
With ActiveSheet
.Columns("A:C").EntireColumn.Delete
.Cells.Validation.Delete
End With
Set Tgt = ActiveWorkbook
TgtPath = Tgt.FullName
Tgt.Save
Tgt.Close
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Workbooks.Open TgtPath
Exit Sub
ErrHandle:
Application.DisplayAlerts = True
MsgBox "An Unexpected Error has occurred."
End Sub
