web
You’re offline. This is a read only version of the page.
close
Skip to main content
Community site session details

Community site session details

Session Id :
Dynamics 365 Community / Blogs / Dynamics 365 Business Central Technical Blogs / Bypass "Auto. Accept Transa...

Bypass "Auto. Accept Transactions" and "Auto. Send Transactions" in IC Journals

Views (13)
Aman Kakkar Profile Picture Aman Kakkar 159

In this blog we will learn about how we can by-pass the Intercompany Setup's "Auto. Send Transactions" in base company and "Auto. Accept Transactions" in the Partner Company while posting IC Journals in the base company. Sometimes, we want to post some IC Journal lines via AL Code, where we don't want to touch the standard process. We can use the below procedures/events that will help us in this particular scenario.

Pre-Requisites-

Regardless of whether you are using the IC Default Template and Batch or a custom Template/Batch, you must configure the IC Default Template and Batch in Intercompany Setup in the Partner Company. Otherwise, Auto-Acceptance of IC transactions will fail in the partner company.

For Auto. Send Transactions-

In the standard report "IC Outbox Export" there’s a function:

procedure ProcessAutoSendOutboxTransactionNo(ICOutboxTransactionNo: Integer)
    var
        ICSetup: Record "IC Setup";
        IsHandled: Boolean;
    begin
        IsHandled := false;
        OnBeforeProcessAutoSendOutboxTransactionNo(ICOutboxTransactionNo, IsHandled);
        if IsHandled then
            exit;

        ICSetup.Get();
        if ICSetup."Auto. Send Transactions" then
            ModifyAndRunOutboxTransactionNo(ICOutboxTransactionNo);
    end;
This checks the Auto-Send boolean before sending transactions to the partner company.

Inside there, it eventually calls - "ModifyAndRunOutboxTransactionNo". This function can be copied into a custom codeunit and invoked wherever you need to bypass the Auto-Send boolean dependency:
local procedure ModifyAndRunOutboxTransactionNo(ICOutboxTransactionNo: Integer)
var
    ICOutboxTransaction: Record "IC Outbox Transaction";
begin
    ICOutboxTransaction.SetRange("Transaction No.", ICOutboxTransactionNo);
    if ICOutboxTransaction.FindFirst() then begin
        ICOutboxTransaction."Line Action" := ICOutboxTransaction."Line Action"::"Send to IC Partner";
        ICOutboxTransaction.Modify();
        RunOutboxTransactions(ICOutboxTransaction);
    end;
end;

For Auto. Accept Transactions-


The standard report "Move IC Trans. to Partner Comp" (Report 513) is used for accepting the inbox transactions, which also raises an event: "OnICInboxTransactionCreated".

This event is subscribed by Codeunit 790 "IC Inbox Outbox Subscribers", where Auto-Accept is checked before enqueuing transactions.
[EventSubscriber(ObjectType::Report, Report::"Move IC Trans. to Partner Comp", 'OnICInboxTransactionCreated', '', false, false)]
    local procedure AcceptOnAfterInsertICInboxTransaction(var Sender: Report "Move IC Trans. to Partner Comp"; var ICInboxTransaction: Record "IC Inbox Transaction"; PartnerCompanyName: Text)
    var
        ICPartner: Record "IC Partner";
        TempRegisteredPartner: Record "IC Partner" temporary;
        FeatureTelemetry: Codeunit "Feature Telemetry";
        ICMapping: Codeunit "IC Mapping";
        ICDataExchange: Interface "IC Data Exchange";
    begin
        ICPartner.SetRange("Inbox Details", PartnerCompanyName);
        if not ICPartner.FindFirst() then
            exit;

        ICDataExchange := ICPartner."Data Exchange Type";
        ICDataExchange.GetICPartnerFromICPartner(ICPartner, TempRegisteredPartner);

        FeatureTelemetry.LogUptake('0000IIX', ICMapping.GetFeatureTelemetryName(), Enum::"Feature Uptake Status"::Used);
        FeatureTelemetry.LogUsage('0000IIY', ICMapping.GetFeatureTelemetryName(), 'IC Inbox Transaction Created');

        if TempRegisteredPartner."Auto. Accept Transactions" then
            if not IsICInboxTransactionReturnedByPartner(ICInboxTransaction."Transaction Source") then
                ICDataExchange.EnqueueAutoAcceptedICInboxTransaction(ICPartner, ICInboxTransaction);
    end;
If you try "Go To Definition" for "EnqueueAutoAcceptedICInboxTransaction", then you will end up landing on an Interface where you will not be able to see any Code.

So better go to Codeunit 532 and search for "EnqueueAutoAcceptedICInboxTransaction" and copy paste it in your custom code. This is basically used for accepting the inbox transactions in the partner company.
procedure EnqueueAutoAcceptedICInboxTransaction(ICPartner: Record "IC Partner"; ICInboxTransaction: Record "IC Inbox Transaction")
var
    JobQueueEntry: Record "Job Queue Entry";
begin
    if not JobQueueEntry.ChangeCompany(ICPartner."Inbox Details") then
        Error(FailedToChangeCompanyErr, JobQueueEntry.TableCaption, ICPartner.Name);

    if not JobQueueEntry.ReadPermission() then
        Error(MissingPermissionToReadTableErr, JobQueueEntry.TableCaption, ICPartner.Name);

    JobQueueEntry."Object Type to Run" := JobQueueEntry."Object Type to Run"::Codeunit;
    JobQueueEntry."Object ID to Run" := Codeunit::"IC Inbox Outbox Subs. Runner";
    JobQueueEntry."Maximum No. of Attempts to Run" := 3;
    JobQueueEntry."Recurring Job" := false;
    JobQueueEntry."Record ID to Process" := ICInboxTransaction.RecordId;
    JobQueueEntry."Job Queue Category Code" := JobQueueCategoryCodeTxt;
    JobQueueEntry."Run in User Session" := false;
    JobQueueEntry.Status := JobQueueEntry.Status::Ready;
    JobQueueEntry.Description := StrSubstNo(AutoAcceptTransactionTxt, ICInboxTransaction."Transaction No.", ICInboxTransaction."IC Partner Code", ICInboxTransaction."Document No.");
    JobQueueEntry.Insert(true);
    CODEUNIT.Run(CODEUNIT::"Job Queue - Enqueue", JobQueueEntry);
end;​​​​​​​

Bringing It Together-

Finally, we can combine both steps into a single reusable procedure and call it whenever posting IC journal lines. I have added a custom procedure that can be used for calling the procedures that we created till now:

procedure AutoSendAndAutoAcceptTransaction(var GenJnlPostLine: Codeunit "Gen. Jnl.-Post Line"; var GenJournalLines: Record "Gen. Journal Line"; ICPartnerCode: Code[20])
var
    ICInboxOutboxMgt: Codeunit ICInboxOutboxMgt;
    ICTransactionNo: Integer;
    ICSetup: Record "IC Setup";
    ICPartner: Record "IC Partner";
    ICInboxTransaction: Record "IC Inbox Transaction";
begin
    GenJnlPostLine.RunWithCheck(GenJournalLines);

    ICTransactionNo := ICInboxOutboxMgt.CreateOutboxJnlTransaction(GenJournalLines, false);
    ICInboxOutboxMgt.CreateOutboxJnlLine(ICTransactionNo, 1, GenJournalLines);

    ModifyAndRunOutboxTransactionNo(ICTransactionNo);

    ICSetup.Get();
    if ICPartner.Get(ICPartnerCode) then begin
        ICInboxTransaction.ChangeCompany(ICPartner."Inbox Details");
        if ICInboxTransaction.Get(ICTransactionNo, ICSetup."IC Inbox Details", ICInboxTransaction."Transaction Source"::"Created by Partner", ICInboxTransaction."Document Type"::" ") then
            EnqueueAutoAcceptedICInboxTransaction(ICPartner, ICInboxTransaction);
    end;
end;
​​​​​​​
Now, when you post your Custom IC Journal Lines — either together with invoices or through custom actions — they will be automatically sent and accepted without requiring the standard Auto-Send or Auto-Accept settings.

If you notice that your custom Enqueue function is being triggered but Auto-Accept still doesn’t complete, check the Job Queue Log Entries for any errors that may have occurred during processing.

Occasionally, you might encounter an error similar to the one shown below.

The IC Inbox Transaction does not exist. Identification fields and values: Transaction No.='257',IC Partner Code='Random',Transaction Source='Created by Partner',Document Type=' '

This can be safely ignored — it happens when the standard Auto-Accept logic runs after your custom code has already accepted the transaction, resulting in a duplicate attempt.

Comments